A função da macro é craftar ouro, e blocos de minérios. Você precisa ter no minimo 9 packs do material para craftar, os materiais configurados são:
Pepira de Ouro,
Ouro,
Diamante,
Esmeralda,
Ferro.
Tenha os 9 packs ou mais no inventário, e ligue a macro. Ao ligar, ela vai esperar até que uma Bancada de Trabalho seja aberta, ou seja, caso seja VIP, a macro vai digitar o comando /bench, caso não seja, olhe quando quiser, para uma Bancada de Trabalho para iniciar.
A macro possui muitos sistemas de segurança, entre eles, dois se destacam. O primeiro é o
AntLag, que caso a macro coloque o item no slot da bancada, e ele volte pro inventário, a macro detecta e recoloca-o no lugar correto. O segundo é o
Return, que, caso algo de errado aconteça, a macro retira todos os itens da bancada, e recomeça.
Caso você feche sem querer a bancada, a macro vai parar.
Você pode
trollar a macro no processo de execução, pois a macro é inteligente, detecta muita coisa e tenta arrumar. Quando você liga-la, tente atrapalhar quando ela começar a colocar os itens, acha que ela vai bugar? Ta enganado.
Código da macro:
- Código principal:
$${
TOGGLE(sleepmacro);
IF(sleepmacro);
LOG("&4&l[Macro] &6SleepCraft &4[OFF]");
STOP();
ELSE;
LOG("&2&l[Macro] &6SleepCraft &2[ON]");
UNSET(start);
ENDIF;
SET(&item_stack,"");
GUI(INVENTORY);
GETSLOT(371,#slot_pepita,9);
GETSLOT(266,#slot_ouro,9);
GETSLOT(264,#slot_diamante,9);
GETSLOT(265,#slot_ferro,9);
GETSLOT(388,#slot_esmeralda,9);
IF(%#slot_pepita%>=9);
SET(#id_minerio,"371");
SET(&name_minerio,"&e&lPEPITA");
SET(start);
SET(&item_stack,"%&item_stack%-");
ENDIF;
IF(%#slot_ouro%>=9);
SET(#id_minerio,"266");
SET(&name_minerio,"&e&lOURO");
SET(start);
SET(&item_stack,"%&item_stack%-");
ENDIF;
IF(%#slot_diamante%>=9);
SET(#id_minerio,"264");
SET(&name_minerio,"&b&lDIAMANTE");
SET(start);
SET(&item_stack,"%&item_stack%-");
ENDIF;
IF(%#slot_ferro%>=9);
SET(#id_minerio,"265");
SET(&name_minerio,"&f&lFERRO");
SET(start);
SET(&item_stack,"%&item_stack%-");
ENDIF;
IF(%#slot_esmeralda%>=9);
SET(#id_minerio,"388");
SET(&name_minerio,"&2&lESMERALDA");
SET(start);
SET(&item_stack,"%&item_stack%-");
ENDIF;
IF(start);
IFMATCHES("%&item_stack%","^--(.*)$");
LOG("&e&l» &7Você deve deixar apenas &9um &7tipo de item para craftar.");
GUI();
TOGGLE(sleepmacro);
STOP();
ELSE;
SET(#item_pack,"");
SET(#getslot,"9");
DO;
GUI(INVENTORY);
GETSLOT(%#id_minerio%,#sleep_slot,%#getslot%);
GETSLOTITEM(%#sleep_slot%,#sleep_id,#sleep_stack);
IF((%#sleep_slot%>=%#getslot%)&&(%#sleep_stack%=64));
INC(#item_pack,1);
#getslot = %#sleep_slot% + 1;
ELSE;
IF(%#sleep_slot%!=-1);
#getslot = %#sleep_slot% + 1;
ENDIF;
ENDIF;
UNTIL((%#sleep_slot%=-1)||(%#item_pack%>8));
IF(%#item_pack%>8);
LOG("&e&l» &7Aguardando Bancada de Trabalho.");
SET(#sleep_shield,"100");
GUI();
DO;
IF(%#sleep_shield%>=100);
IF(%HITID%=58);
KEY(USE);
SET(#sleep_shield,"");
ELSE;
ECHO("/bench");
SET(#sleep_shield,"");
ENDIF;
ENDIF;
INC(#sleep_shield,1);
UNTIL(%GUI%="GUICRAFTING");
WAIT(5T);
LOG("&e&l» &7Crafting %&name_minerio%&7's.");
SET(guicrafting);
DO;
DO;
UNSAFE;
FOR(#sleep_slot,1,9);
GETSLOTITEM(%#sleep_slot%,#sleep_id,#sleep_stack);
IF(%#sleep_id%=0);
SET(#craft_vazio,"%#sleep_slot%");
SET(&craft_vazio,"LOADING");
BREAK;
ELSE;
SET(&craft_vazio,"CONTINUE");
ENDIF;
NEXT;
IF(%&craft_vazio%="LOADING");
SET(#getslot,"10");
DO;
RANDOM(#random_slot,9,1);
GETSLOTITEM(%#random_slot%,#sleep_id,#sleep_stack);
IF(%#sleep_id%!=0);
SET(#random_slot,"%#craft_vazio%");
ENDIF;
DO;
GETSLOT(%#id_minerio%,#sleep_slot,%#getslot%);
GETSLOTITEM(%#sleep_slot%,#sleep_id,#sleep_stack);
#getslot = %#sleep_slot% + 1;
UNTIL(%#sleep_stack%=64);
SLOTCLICK(%#sleep_slot%,L,FALSE);
WAIT(50MS);
SLOTCLICK(%#random_slot%,L,FALSE);
WAIT(50MS);
GETSLOTITEM(%#random_slot%,#sleep_id,#sleep_stack);
UNTIL(%#random_slot%!=0);
ENDIF;
ENDUNSAFE;
UNTIL(%&craft_vazio%="CONTINUE");
SET(#sleep_shield,"");
SET(#craft_c,"");
UNSET(error);
DO;
GETSLOTITEM(0,#sleep_id,#sleep_stack);
IF((%#sleep_id%=41)||(%#sleep_id%=266)||(%#sleep_id%=57)||(%#sleep_id%=42)||(%#sleep_id%=133));
INC(#craft_c,1);
ELSE;
INC(#sleep_shield,1);
IF(%#sleep_shield%>=25);
SET(error);
BREAK;
ENDIF;
ENDIF;
IF(%#craft_c%>=7);
SLOTCLICK(0,L,TRUE);
WAIT(1T);
BREAK;
ENDIF;
LOOP;
IF(%GUI%!="GUICRAFTING");
UNSET(guicrafting);
BREAK;
ENDIF;
IF(error);
DO;
GETSLOT(%#id_minerio%,#sleep_slot,1);
IF((%#sleep_slot%<=9)&&(%#sleep_slot%!=-1));
SLOTCLICK(%#sleep_slot%,L,TRUE);
WAIT(1T);
ENDIF;
UNTIL((%#sleep_slot%>=9)||(%#sleep_slot%=-1));
ELSE;
SET(#item_pack,"");
SET(#getslot,"10");
DO;
GETSLOT(%#id_minerio%,#sleep_slot,%#getslot%);
GETSLOTITEM(%#sleep_slot%,#sleep_id,#sleep_stack);
IF((%#sleep_slot%>=%#getslot%)&&(%#sleep_stack%=64));
INC(#item_pack,1);
#getslot = %#sleep_slot% + 1;
ELSE;
IF(%#sleep_slot%!=-1);
#getslot = %#sleep_slot% + 1;
ENDIF;
ENDIF;
UNTIL((%#sleep_slot%=-1)||(%#item_pack%>8));
ENDIF;
WHILE(%#item_pack%>8);
IF(guicrafting);
LOG("&e&l» &7FIM.");
ELSE;
LOG("&e&l» &7Bancada de Trabalho fechada.");
ENDIF;
GUI();
TOGGLE(sleepmacro);
STOP();
ELSE;
LOG("&e&l» &7%&name_minerio%&7's insuficiêntes.");
GUI();
TOGGLE(sleepmacro);
STOP();
ENDIF;
ENDIF;
ELSE;
LOG("&e&l» &7Não foi encontrado minério.");
GUI();
TOGGLE(sleepmacro);
STOP();
ENDIF;
}$$
OBS: Precisa ser vip para usar o /mc
OBS²: Nao é por onchat e nao precisa de scripts
externos em eventos
