Olá galera!
Após varios dias nesse forum procurando uma macro de pesca, nenhuma encaixou no que eu precisava, então eu resolvi fazer a minha, e hoje estou aqui para compartilhar com vocês!
Changelog
O que ela faz:
- Repara (Só precisa de 1 vara na mao, o macro repara ela quando precisar)
- Pergunta quais itens você quer que guarda e salva para as proximas vezes que você ativar não precisar escolher de novo (Ela já guarda os livros do tesouro automaticamente, e apenas ignora a linha no inventario)
- Guarda os itens no /bau (por isso somente vip), não tendo a necessidade de fazer uma trap de bau e com isso também não precisará parar a pesca para guardar os itens
- Liga automaticamente após reinicio do servidor
Edit: É necessário ter instalado o mod de autofish e autojoin(se quiser reconectar automatico apos reiniciar o servidor)
Instalação da macro:
- Antes de tudo, você precisa ir no pesqueiro vip e dar /sethome naldipescaria no lugar que você achar melhor para pescar.
- Você precisará colocar a vara no primeiro slot da mão(importante), e linha em qualquer lugar do inventário e quantos packs quiser.
- Começando pela macro principal, eu escolhi o botão 0 do teclado numérico como a tecla padrão para reativar a macro no onchat, então sugiro que você escolha essa tecla para não ter problemas, ou se quiser pode alterar a tecla escolhida e estarei ensinando alguns passos abaixo
- Clique na tecla e digite $$<naldipesca.txt> no campo como na imagem
- Após, clique no botão "Arquivos" no menu de ações na lateral direita
- Irá abrir uma janela, e nela você digitará o mesmo nome do arquivo e clicará em "Criar"
- Abrirá uma tela de edição de texto, você irá colar o código da macro principal nessa parte, clicará em salvar, e depois em salvar novamente.
- Já o procedimento para a instalar o onchat, só é diferente o comeco, você precisará alterar a aba para os demais eventos clicando na seta no topo da tela de edicao de macros
- Após mudar de aba, você clicará no botão onChat, igual na print abaixo
- Clique na tecla e digite $$<naldipescaonchat.txt> no campo como na imagem
- Irá abrir uma janela, e nela você digitará o mesmo nome do arquivo e clicará em "Criar"
- Abrirá uma tela de edição de texto, você irá colar o código do onchat nessa parte, clicará em salvar, e depois em salvar novamente.
Precisa apenas ficar em cima de um bloco de ferro, e digitar /sethome naldireparacao
- O codigo de religar a macro está vinculado a tecla 0 do teclado numérico, se você quiser alterar, vá na linha 7 e 12 e altere a tecla. A lista dos codigos das teclas correspondentes está aqui https://minecraft.gamepedia.com/Key_codes
- Altere o texto "SUA_SENHA" na linha 5 pela sua senha para logar no servidor quando ele iniciar
Qualquer duvida, sugestão, problema ou critica, comente ai e eu responderei assim que puder!
Espero ajudar a galera
Obs: O codigo está todo comentado, se alguem quiser fazer alguma alteração fique a vontade!
Após varios dias nesse forum procurando uma macro de pesca, nenhuma encaixou no que eu precisava, então eu resolvi fazer a minha, e hoje estou aqui para compartilhar com vocês!
Changelog
- 0.1: Adicionado melhorias no codigo onchat pois não estava reconectando de vez em quando por causa de lag do servidor ao reiniciar
- 0.2: Aumentado intervalo inicial ao jogar a isca da vara pois para alguns players o intervalo estava rapido e a macro não conseguia lançar a isca
O que ela faz:
- Repara (Só precisa de 1 vara na mao, o macro repara ela quando precisar)
- Pergunta quais itens você quer que guarda e salva para as proximas vezes que você ativar não precisar escolher de novo (Ela já guarda os livros do tesouro automaticamente, e apenas ignora a linha no inventario)
- Guarda os itens no /bau (por isso somente vip), não tendo a necessidade de fazer uma trap de bau e com isso também não precisará parar a pesca para guardar os itens
- Liga automaticamente após reinicio do servidor
Edit: É necessário ter instalado o mod de autofish e autojoin(se quiser reconectar automatico apos reiniciar o servidor)
Instalação da macro:
- Antes de tudo, você precisa ir no pesqueiro vip e dar /sethome naldipescaria no lugar que você achar melhor para pescar.
- Você precisará colocar a vara no primeiro slot da mão(importante), e linha em qualquer lugar do inventário e quantos packs quiser.
- Começando pela macro principal, eu escolhi o botão 0 do teclado numérico como a tecla padrão para reativar a macro no onchat, então sugiro que você escolha essa tecla para não ter problemas, ou se quiser pode alterar a tecla escolhida e estarei ensinando alguns passos abaixo
- Clique na tecla e digite $$<naldipesca.txt> no campo como na imagem
- Após, clique no botão "Arquivos" no menu de ações na lateral direita
- Irá abrir uma janela, e nela você digitará o mesmo nome do arquivo e clicará em "Criar"
- Abrirá uma tela de edição de texto, você irá colar o código da macro principal nessa parte, clicará em salvar, e depois em salvar novamente.
- Já o procedimento para a instalar o onchat, só é diferente o comeco, você precisará alterar a aba para os demais eventos clicando na seta no topo da tela de edicao de macros
- Após mudar de aba, você clicará no botão onChat, igual na print abaixo
- Clique na tecla e digite $$<naldipescaonchat.txt> no campo como na imagem
- Irá abrir uma janela, e nela você digitará o mesmo nome do arquivo e clicará em "Criar"
- Abrirá uma tela de edição de texto, você irá colar o código do onchat nessa parte, clicará em salvar, e depois em salvar novamente.
Precisa apenas ficar em cima de um bloco de ferro, e digitar /sethome naldireparacao
- O codigo de religar a macro está vinculado a tecla 0 do teclado numérico, se você quiser alterar, vá na linha 7 e 12 e altere a tecla. A lista dos codigos das teclas correspondentes está aqui https://minecraft.gamepedia.com/Key_codes
- Altere o texto "SUA_SENHA" na linha 5 pela sua senha para logar no servidor quando ele iniciar
Código:
$${
ifmatches(%CHATCLEAN%,"^» CraftLandia Propano \(www.craftlandia.com.br\)$");
wait(3);
if(@naldipesca);
echo(/login SUA_SENHA);
wait(2);
@&naldipescacontinuar=S;
wait(500ms);[/COLOR]
press(NUMPAD0);
wait(5);
log(&6[Naldi]&b Reiniciando a macro Pesca vip...);
do;
@&naldipescacontinuar=S;
press(NUMPAD0);
wait(5);
until(@naldipesca);
log(&6[Naldi]&b Macro Pesca vip reiniciada com sucesso!);
endif;
endif;
}$$
Código:
$${
if(@naldipesca);
unset(@naldipesca);
log(&6[Naldi]&b Pesca vip &4[Off]);
ifmatches(%@&naldipescacontinuar%,N);
echo(/g &bDesativando a macro &aNaldi Pesca Vip &b(update 0.2));
endif;
stop;
else;
set(@naldipesca);
// Se já tiver itens selecionados para serem guardados
if(@&naldipescaguardar);
ifmatches(%@&naldipescacontinuar%,S);
else;
do;
prompt(@&naldipescacontinuar, $$?, Deseja continuar com os itens ja selecionados? Digite 'S' p/ SIM e 'N' para NAO);
ifmatches(%@&naldipescacontinuar%,S);
break;
endif;
ifmatches(%@&naldipescacontinuar%,N);
break;
endif;
loop;
endif;
else;
// Seta continuar = "Não" como padrão se for a primeira vez
@&naldipescacontinuar=N;
endif;
// Se não quiser continuar com os itens selecionados ou for a primeira vez, faz a escolha dos itens
ifmatches(%@&naldipescacontinuar%,N);
&item=none;
// Por padrão guarda os livros do tesouro
@&naldipescaguardar=^written_book:0$;
do;
prompt(&item,$$i:d,Selecione os itens para guardar! (Deixe em branco para sair));
ifmatches(%&item%,^air$|^:0$|^none$);
break;
else;
// Adiciona a lista de itens o item escolhido para ser guardado
@&naldipescaguardar=%@&naldipescaguardar%|^%&item%$;
endif;
loop;
endif;
// Seta continuar = "Não" para na proxima vez que abrir fazer a pergunta novamente
@&naldipescacontinuar=N;
log(&6[Naldi]&b Pesca vip Propano &a[On]);
echo(/g &bAtivando a macro &aNaldi Pesca Vip &b(update 0.2));
echo(/home naldipescaria);
wait(7);
// Salva a posição que o player está olhando
#yaw=%YAW% + 180;
#pitch=%PITCH%;
// Por segurança vai pra outro slot que não tenha a vara para cancelar a pesca se estiver ativa
slot(9);
wait(1);
slot(1);
wait(2);
key(use);
wait(1);
// Contador de loop para verificar inventario
#temp = 0;
do;
// Força olhar para o mesmo rumo quando iniciou
look(%#yaw%,%#pitch%);
// Incrementa contador
inc(#temp);
// Checa se precisa reparar a vara
if(%DURABILITY%<20);
slot(2);
wait(1);
echo(/home naldireparacao);
wait(7);
keydown(jump);
wait(1);
keyup(jump);
wait(1);
look(,90);
// Repara 3 vezes
do(3);
slot(1);
key(use);
key(attack);
wait(300ms);
loop;
// Volta para a pescaria
echo(/home naldipescaria);
wait(7);
slot(2);
wait(1);
slot(1);
wait(1);
key(use);
endif;
if(%#temp%>=50);
#temp = 0;
// Abre o inventario
do;
gui(inventory);
wait(1);
until(%GUI%="GUIINVENTORY");
#vazio = 0;
// Checa o inventario
for(#i,9,44);
// Pega o id do item e a durabilidade/qualidade do item (para diferenciar itens especificos com mesmo nome, peixes por exemplo fish, fish:1)
getslotitem(%#i%,&id,,#durabilidade);
&id = %&id%:%#durabilidade%;
// Se for espaço vazio, aumenta contador
ifmatches(%&id%,^air:0$);
inc(#vazio);
else;
// Se for itens a guardar ou linha, ignora
ifmatches(%&id%,%@&naldipescaguardar%|^string:0$);
else;
// Se for o slot da vara, ignora
if(%#i%=36);
else;
// Joga fora e incrementa o contador de slot vazio
slotclick(%#i%);
slotclick(-999);
inc(#vazio);
wait(100ms);
endif;
endif;
endif;
next;
// Fecha inventario
gui();
wait(1);
// Inicia o armazenamento de itens no bau vip se tiver 3 espaços ou menos vazio
if(%#vazio%<=3);
echo(/bau);
wait(7);
for(#i,54,89);
// Pega o id do item e a durabilidade/qualidade do item (para diferenciar itens especificos com mesmo nome, peixes por exemplo fish, fish:1)
getslotitem(%#i%,&id,,#durabilidade);
&id = %&id%:%#durabilidade%;
// Se for um item da lista para guardar
ifmatches(%&id%,%@&naldipescaguardar%);
// E não for a vara principal
if(%#i%!=81);
// Guarda o item no bau
slotclick(%#i%,l,true);
endif;
wait(150ms);
endif;
next;
// Fecha o inventario
gui();
endif;
endif;
wait(300ms);
loop;
endif;
}$$Qualquer duvida, sugestão, problema ou critica, comente ai e eu responderei assim que puder!
Espero ajudar a galera
Obs: O codigo está todo comentado, se alguem quiser fazer alguma alteração fique a vontade!
Última edição:
